STM32 com a API do Arduino (4/4): minicontrolador

Seu minicontrolador terá três estados:

• Potenciômetro abaixo do limite: cor verde.
• Potenciômetro acima do limite: cor vermelha.
• Botão pressionado: cor azul, mesmo que o potenciômetro diga outra coisa.

O desafio não é apenas copiar o programa. No final, você deverá ter um minicontrolador testado que lê uma entrada, decide um estado, altera o LED RGB, registra evidências por meio do Serial e incorpora uma pequena melhoria que você consegue defender.

Antes de programar, pense como se estivesse testando um pequeno produto. Um bom teste deve dizer o que você moverá, qual cor espera ver e quais dados do Serial confirmariam que o controlador tomou a decisão correta.

O programa inicial imprimirá linhas exatamente neste formato: state=<green/red/manual> pot1=<leitura ADC> button=<released/pressed>.

A função setRgb(red, green, blue) evita repetir três linhas toda vez que você muda a cor. Cada argumento representa um brilho PWM entre 0 e 255. O limite inicial é de 600 contagens ADC, mas você deverá compará-lo com leituras reais.

bool armazena true ou false. Como o botão 1 é ativo em LOW, o valor booleano buttonPressed se torna verdadeiro quando a leitura é LOW. if / else if / else verifica os ramos de cima para baixo e executa apenas o primeiro ramo verdadeiro; por isso, a condição manual deve vir primeiro. const char* state armazena um rótulo de texto curto para Serial; você não precisa alterar essa sintaxe.

Você copiará um programa inicial, testará e ajustará. O resultado final deverá ser um controlador pequeno mas completo: lê POT_1, decide com THRESHOLD, permite o modo manual com BUTTON_1, altera o LED RGB e registra pelo Serial qual estado foi escolhido.

#include <Arduino.h>

const int POT_1 = PC0;
const int BUTTON_1 = PC5;  // Ativo LOW
const int RGB_RED = PA8;
const int RGB_GREEN = PA9;
const int RGB_BLUE = PA10;

const int THRESHOLD = 600;

void setRgb(int red, int green, int blue) {
  analogWrite(RGB_RED, red);
  analogWrite(RGB_GREEN, green);
  analogWrite(RGB_BLUE, blue);
}

void setup() {
  pinMode(BUTTON_1, INPUT);
  pinMode(RGB_RED, OUTPUT);
  pinMode(RGB_GREEN, OUTPUT);
  pinMode(RGB_BLUE, OUTPUT);
  Serial.begin(115200);
}

void loop() {
  int reading = analogRead(POT_1);
  bool buttonPressed = digitalRead(BUTTON_1) == LOW;
  const char* state;

  if (TODO_MANUAL_CONDITION) { // TODO 1: verdadeiro somente quando o modo manual é solicitado
    setRgb(0, 0, 255);
    state = "manual";
  } else if (TODO_HIGH_CONDITION) { // TODO 2: leitura no limite ou acima dele
    setRgb(255, 0, 0);
    state = "red";
  } else {
    setRgb(0, 180, 0);
    state = "green";
  }

  Serial.print("state=");
  Serial.print(state);
  Serial.print(" pot1=");
  Serial.print(reading);
  Serial.print(" button=");
  if (buttonPressed) {
    Serial.println("pressed");
  } else {
    Serial.println("released");
  }

  delay(100);
}

Use seis linhas na tabela. As linhas 1 a 3 documentam o programa inicial e devem ser concluídas antes da modificação. As linhas 4 a 6 repetem os mesmos três casos após a calibração e a melhoria do diagnóstico. Cada linha deve relacionar entrada, decisão e evidência do hardware real:

• Linhas 1 e 4: B1 solto, potenciômetro na posição inferior de calibração.
• Linhas 2 e 5: B1 solto, potenciômetro na posição superior de calibração.
• Linhas 3 e 6: B1 mantido pressionado na posição superior de calibração.
• Em Valores vistos no Serial, copie aproximadamente state, pot1 e button.
• Nas linhas melhoradas, copie também o novo campo margin. Recrie cada posição dentro de cerca de 30 contagens ADC de sua leitura inicial.

Substitua 600 em THRESHOLD pelo seu ponto médio arredondado. Em seguida, adicione um diagnóstico Serial logo após o valor impresso de pot1: imprima margin= e depois reading - THRESHOLD. Uma margem negativa significa abaixo do limite calibrado; zero ou uma margem positiva significa igual ou superior a ela.

Salve, compile, faça upload e reabra Serial em 115200 baud. Repita os mesmos três casos de teste e preencha as linhas aprimoradas 4 a 6. O diagnóstico só é útil se o estado visível, state, e o sinal de margin concordarem; o modo manual ainda deve ter prioridade, mesmo quando a margem for positiva.