STM32 con Arduino API (4/4): mini-controlador

Tu mini-controlador tendrá tres estados:

- Potenciómetro por debajo del umbral: color verde.
- Potenciómetro por encima del umbral: color rojo.
- Botón pulsado: color azul, aunque el potenciómetro indique otra cosa.

El reto no es solo copiar el programa. Al final debes tener un mini-controlador
probado: lee una entrada, decide un estado, cambia el RGB, escribe evidencia por
Serial y conserva una mejora pequeña que puedas defender.

Antes de programar, piensa como si fueras a probar un producto pequeño. Una
buena prueba debe decir qué vas a tocar, qué color esperas ver y qué dato de
Serial confirmaría que el controlador tomó la decisión correcta.

La función setRgb evita repetir tres líneas cada vez que quieras cambiar de
color. El umbral inicial es 600, pero tendrás que comprobar si tiene sentido
con tus lecturas reales.

Vas a copiar un programa base, probarlo y ajustarlo. El resultado final debe ser
un controlador pequeño pero completo: lee POT_1, decide con UMBRAL, permite
modo manual con BOTON_1, cambia el RGB y escribe por Serial qué estado eligió.

#include <Arduino.h>

const int POT_1 = PC0;
const int BOTON_1 = PC5;  // Activo en LOW
const int RGB_ROJO = PA8;
const int RGB_VERDE = PA9;
const int RGB_AZUL = PA10;

const int UMBRAL = 600;

void setRgb(int rojo, int verde, int azul) {
  analogWrite(RGB_ROJO, rojo);
  analogWrite(RGB_VERDE, verde);
  analogWrite(RGB_AZUL, azul);
}

void setup() {
  pinMode(BOTON_1, INPUT);
  pinMode(RGB_ROJO, OUTPUT);
  pinMode(RGB_VERDE, OUTPUT);
  pinMode(RGB_AZUL, OUTPUT);
  Serial.begin(115200);
}

void loop() {
  int lectura = analogRead(POT_1);
  bool botonPulsado = digitalRead(BOTON_1) == LOW;
  const char* estado;

  if (botonPulsado) {
    setRgb(0, 0, 255);
    estado = "manual";
  } else if (lectura >= UMBRAL) {
    setRgb(255, 0, 0);
    estado = "rojo";
  } else {
    setRgb(0, 180, 0);
    estado = "verde";
  }

  Serial.print("estado=");
  Serial.print(estado);
  Serial.print(" pot1=");
  Serial.print(lectura);
  Serial.print(" boton=");
  Serial.println(botonPulsado ? "pulsado" : "suelto");

  delay(100);
}

Rellena la tabla después de probar el controlador. Cada fila debe conectar una
entrada con una decisión y una evidencia. Usa al menos tres filas y deja vacías
las demás si Teach muestra más:

- Fila 1: potenciómetro bajo el umbral.
- Fila 2: potenciómetro sobre el umbral.
- Fila 3: botón 1 pulsado para comprobar el modo manual.
- En Valores vistos por Serial, copia estado, pot1 y boton de forma
aproximada.
- Si modificas UMBRAL, escribe el valor final que usaste.

Elige una mejora pequeña:

- Cambiar el umbral.
- Cambiar los colores o el brillo.
- Hacer que el modo manual parpadee en azul.
- Añadir una línea de Serial que explique el estado (verde, rojo o manual).